v3.6.4

=====================================================================

--- Changes ------------------------------

- Introduced lazy environment variable checking on ECR_LOGIN

plugins/kubectl/.config/env.template

@@ -0,0 +1,2 @@
+#!/bin/zsh
+export SCWRYPTS_KUBECTL_REDIS=

plugins/kubectl/.config/env.template.descriptions

@@ -0,0 +1 @@
+SCWRYPTS_KUBECTL_REDIS | (currently only 'managed') 'managed' or 'custom' redis configuration

plugins/kubectl/.config/static/redis.zsh

@@ -0,0 +1,4 @@
+export SCWRYPTS_KUBECTL_REDIS_HOST__managed=127.0.0.1
+export SCWRYPTS_KUBECTL_REDIS_PORT__managed=26379
+export SCWRYPTS_KUBECTL_REDIS_AUTH__managed=
+export SCWRYPTS_KUBECTL_REDIS_KEY_PREFIX__managed=

plugins/kubectl/README.md

@@ -0,0 +1,10 @@
+# Kubernetes `kubectl` Helper Plugin
+
+Leverages a local `redis` application to quickly and easily set an alias `k` for `kubectl --context <some-context> --namespace <some-namespace>`.
+Much like scwrypts environments, `k` aliases are *only* shared amongst session with the same `SCWRYPTS_ENV` to prevent accidental cross-contamination.
+
+
+## Getting Started
+
+Enable the plugin in `~/.config/scwrypts/config.zsh` by adding `SCWRYPTS_PLUGIN_ENABLED__KUBECTL=1`.
+Use `k` as your new `kubectl` and checkout `k --help` and `k meta --help`.

plugins/kubectl/driver/kubectl.completion.zsh

@@ -0,0 +1,31 @@
+#####################################################################
+command -v compdef >/dev/null 2>&1 || return 0
+#####################################################################
+
+_k() {
+	local C=$(k meta get context)
+	local NS=$(k meta get namespace)
+
+	local KUBEWORDS=(kubectl)
+	[ $C  ] && KUBEWORDS+=(--context $C)
+	[ $NS ] && KUBEWORDS+=(--namespace $NS)
+
+	words="$KUBEWORDS ${words[@]:1}"
+	_kubectl
+}
+
+compdef _k  k
+
+#####################################################################
+_h() {
+	local C=$(k meta get context)
+	local NS=$(k meta get namespace)
+
+	local KUBEWORDS=(kubectl)
+	[ $C  ] && KUBEWORDS+=(--context $C)
+	[ $NS ] && KUBEWORDS+=(--namespace $NS)
+
+	words="$KUBEWORDS ${words[@]:1}"
+	_helm
+}
+compdef _h  h

plugins/kubectl/driver/kubectl.driver.zsh

@@ -0,0 +1,195 @@
+[[ $SCWRYPTS_KUBECTL_DRIVER_READY -eq 1 ]] && return 0
+
+unalias k h >/dev/null 2>&1
+k() { _SCWRYPTS_KUBECTL_DRIVER kubectl $@; }
+h() { _SCWRYPTS_KUBECTL_DRIVER helm $@; }
+
+
+_SCWRYPTS_KUBECTL_DRIVER() {
+	[ ! $SCWRYPTS_ENV ] && {
+		ERROR "must set SCWRYPTS_ENV in order to use '$(echo $CLI | head -c1)'"
+		return 1
+	}
+
+	which REDIS >/dev/null 2>&1 \
+		|| eval "$(scwrypts -n --name meta/get-static-redis-definition --type zsh --group kubectl)"
+
+	local CLI="$1"; shift 1
+
+	local SCWRYPTS_GROUP CUSTOM_COMMANDS=(meta)
+	for SCWRYPTS_GROUP in ${SCWRYPTS_GROUPS[@]}
+	do
+		CUSTOM_COMMANDS+=($(eval echo '$SCWRYPTS_KUBECTL_CUSTOM_COMMANDS__'$SCWRYPTS_GROUP))
+	done
+
+	##########################################
+
+	local USAGE="
+		usage: - [...args...] [...options...] -- [...$CLI options...]
+
+		args: -
+
+		options: -
+		  --subsession [0-9]   use indicated subsession (use for script clarity instead of positional arg)
+
+		  -h, --help      display this help dialogue
+		  -v, --verbose   output debugging information
+
+		description: -
+	"
+
+	local USAGE__usage=$(echo $CLI | head -c1) 
+
+	local USAGE__args="$(
+		{
+			echo "\\033[0;32m[0-9]\\033[0m^if the first argument is a number 0-9, uses or creates a subsession (default 0)"
+			echo " ^ "
+			for C in ${CUSTOM_COMMANDS[@]}
+			do
+				echo "\\033[0;32m$C\\033[0m^$(SCWRYPTS_KUBECTL_CUSTOM_COMMAND_DESCRIPTION__$C 2>/dev/null)"
+			done 
+		} | column -ts '^'
+	)"
+
+	local USAGE__options="
+		-n, --namespace   set the namespace
+		-k, --context     set the context
+	"
+
+	local USAGE__description="
+		Provides 'k' (kubectl) and 'h' (helm) shorthands to the respective
+		utility. These functions leverage redis and scwrypts environments to
+		allow quick selection of contexts and namespaces usable across all
+		active shell instances.
+		
+		The scwrypts group 'kubectl' has simple selection executables for
+		kubecontext and namespace, but also provides the library to enable
+		enriched, use-case-sensitive setup of kubernetes context.
+
+		All actions are scoped to the current SCWRYPTS_ENV
+		  currently : \\033[0;33m$SCWRYPTS_ENV\\033[0m
+		  
+		"
+
+	##########################################
+	
+	local USER_ARGS=()
+
+	local CUSTOM_COMMAND=0
+	local VERBOSE=0
+	local HELP=0
+	local ERRORS=0
+
+	local COMMAND_SWITCH_CASE="@($(echo $CUSTOM_COMMANDS | sed 's/ /|/g'))"
+
+	[ ! $SUBSESSION ] && local SUBSESSION=0
+	[[ $1 =~ ^[0-9]$ ]] && SUBSESSION=$1 && shift 1
+
+	while [[ $# -gt 0 ]]
+	do
+		case $1 in
+			meta )
+				CUSTOM_COMMAND=$1
+				SCWRYPTS_KUBECTL_CUSTOM_COMMAND_PARSE__$1 ${@:2}
+				break
+				;;
+
+			-v | --verbose ) VERBOSE=1 ;;
+			-h | --help    ) HELP=1 ;;
+
+			--subsession ) SUBSESSION=$2; shift 1 ;;
+
+			-n | --namespace )
+				echo "TODO: set namespace ('$2')" >&2
+				USER_ARGS+=(--namespace $2); shift 1
+				;;
+
+			-k | --context | --kube-context )
+				echo "TODO: set context ('$2')" >&2
+				[[ $CLI =~ ^helm$    ]] && USER_ARGS+=(--kube-context $2)
+				[[ $CLI =~ ^kubectl$ ]] && USER_ARGS+=(--context $2)
+				shift 1
+				;;
+
+			-- ) shift 1; break ;;
+
+			* )
+				[ ! $CUSTOM_COMMAND ] && {
+					for C in ${CUSTOM_COMMANDS[@]}
+					do
+						[[ $1 =~ ^$C$ ]] && {
+							SCWRYPTS_KUBECTL_CUSTOM_COMMAND_PARSE__$1 ${@:2}
+							break
+						}
+					done
+				}
+				USER_ARGS+=($1)
+				;;
+		esac
+		shift 1
+	done
+
+	while [[ $# -gt 0 ]]; do USER_ARGS+=($1); shift 1; done
+
+
+	CHECK_ERRORS --no-fail || return 1
+
+	[[ $HELP -eq 1 ]] && { USAGE; return 0; }
+
+	#####################################################################
+
+	local STRICT=$(_SCWRYPTS_KUBECTL_SETTINGS get strict || echo 1)
+
+	case $CUSTOM_COMMAND in
+		0 )
+			local CLI_ARGS=()
+
+			local CONTEXT=$(k meta get context)
+			local NAMESPACE=$(k meta get namespace)
+
+			[ $CONTEXT ] && [[ $CLI =~ ^helm$    ]] && CLI_ARGS+=(--kube-context $CONTEXT)
+			[ $CONTEXT ] && [[ $CLI =~ ^kubectl$ ]] && CLI_ARGS+=(--context $CONTEXT)
+
+			[[ $STRICT -eq 1 ]] && {
+				[ $CONTEXT   ] || ERROR "missing kubectl 'context'"
+				[ $NAMESPACE ] || ERROR "missing kubectl 'namespace'"
+
+				CHECK_ERRORS --no-fail --no-usage || {
+					ERROR "with 'strict' settings enabled, context and namespace must be set!"
+					REMINDER "
+						these values can be set directly with
+							$(echo $CLI | head -c1) meta set (namespace|context)
+					"
+
+					return 2
+				}
+			}
+
+			[ $NAMESPACE ] && CLI_ARGS+=(--namespace $NAMESPACE)
+			[[ $VERBOSE -eq 1 ]] && {
+				INFO "
+					context '$CONTEXT'
+					namespace '$NAMESPACE'
+					environment '$SCWRYPTS_ENV'
+					subsession '$SUBSESSION'
+					"
+				STATUS "running $CLI ${CLI_ARGS[@]} ${USER_ARGS[@]}"
+			} || {
+				[[ $(_SCWRYPTS_KUBECTL_SETTINGS get context) =~ ^show$ ]] && {
+					INFO "$SCWRYPTS_ENV.$SUBSESSION : $CLI ${CLI_ARGS[@]} ${USER_ARGS[@]}"
+				}
+			}
+			$CLI ${CLI_ARGS[@]} ${USER_ARGS[@]}
+			;;
+		* ) SCWRYPTS_KUBECTL_CUSTOM_COMMAND__$CUSTOM_COMMAND ${USER_ARGS[@]} ;;
+	esac
+}
+
+_SCWRYPTS_KUBECTL_SETTINGS() {
+	# (get setting-name) or (set setting-name setting-value)
+	REDIS h$1 ${SCWRYPTS_ENV}:kubectl:settings ${@:2} | grep .
+}
+
+#####################################################################
+source ${0:a:h}/kubectl.completion.zsh
+source ${0:a:h}/meta.zsh

plugins/kubectl/driver/meta.zsh

@@ -0,0 +1,140 @@
+SCWRYPTS_KUBECTL_CUSTOM_COMMAND_PARSE__meta() {
+	USAGE__usage+=" meta"
+	USAGE__args="
+	- get     output value of meta variable
+	- set     interactively configure value of meta variable
+	- clear   clear current subsession variables
+
+	(settings args)
+	- show   output context for every command
+	- hide   (default) hide output context for every command
+
+	- strict   (default) require context *and* namespace to be set
+	- loose    do not require context and namespace to be set
+	"
+	USAGE__options=''
+	USAGE__description=$(SCWRYPTS_KUBECTL_CUSTOM_COMMAND_DESCRIPTION__meta)
+
+	META_SUBARGS="
+	- namespace
+	- context
+	"
+
+	while [[ $# -gt 0 ]]
+	do
+		case $1 in
+			-h | --help ) HELP=1 ;;
+
+			set ) 
+				USAGE__usage+=" set"
+				USAGE__args="set (namespace|context)"
+				USAGE__description="interactively set a namespace or context for '$SCWRYPTS_ENV'"
+				case $2 in
+					namespace | context ) USER_ARGS+=($1 $2) ;;
+					-h | --help ) HELP=1 ;;
+
+					* ) ERROR "cannot set '$2'" ;;
+				esac
+				shift 1
+				;;
+
+			get )
+				USAGE__usage+=" get"
+				USAGE__args="get (namespace|context|all)"
+				USAGE__description="output the current namespace or context for '$SCWRYPTS_ENV'"
+				case $2 in
+					namespace | context | all ) USER_ARGS+=($1 $2) ;;
+
+					-h | --help ) HELP=1 ;;
+
+					* ) ERROR "cannot get '$2'" ;;
+				esac
+				shift 1
+				;;
+
+			copy )
+				USAGE__usage+=" copy"
+				USAGE__args+="copy [0-9]"
+				USAGE__description="copy current subsession ($SUBSESSION) to target subsession id"
+				case $2 in
+					[0-9] ) USER_ARGS+=($1 $2) ;;
+					-h | --help ) HELP=1 ;;
+					* ) ERROR "target session must be a number [0-9]" ;;
+				esac
+				shift 1
+				;;
+
+			clear | show | hide | strict | loose ) USER_ARGS+=($1) ;;
+
+			* ) ERROR "no meta command '$1'"
+		esac
+		shift 1
+	done
+}
+
+SCWRYPTS_KUBECTL_CUSTOM_COMMAND__meta() {
+	case $1 in
+		get )
+			[[ $2 =~ ^all$ ]] && {
+				local CONTEXT=$(REDIS get --prefix current:context | grep . || echo "\\033[1;31mnone set\\033[0m")
+				local NAMESPACE=$(REDIS get --prefix current:namespace | grep . || echo "\\033[1;31mnone set\\033[0m")
+				echo "
+					environment : $SCWRYPTS_ENV
+					context     : $CONTEXT
+					namespace   : $NAMESPACE
+
+					CLI settings
+					  command context : $(_SCWRYPTS_KUBECTL_SETTINGS get context)
+					      strict mode : $([[ $STRICT -eq 1 ]] && echo "on" || echo "\\033[1;31moff\\033[0m")
+					" | sed 's/^	\+//' >&2
+				return 0
+			}
+
+			REDIS get --prefix current:$2
+			;;
+
+		set )
+			scwrypts -n --name set-$2 --type zsh --group kubectl -- --subsession $SUBSESSION >/dev/null \
+				&& SUCCESS "$2 set"
+			;;
+
+		copy )
+			: \
+				&& STATUS "copying $1 to $2" \
+				&& scwrypts -n --name set-context --type zsh --group kubectl -- --subsession $2 $(k meta get context | grep . || echo 'reset') \
+				&& scwrypts -n --name set-namespace --type zsh --group kubectl -- --subsession $2 $(k meta get namespace | grep . || echo 'reset') \
+				&& SUCCESS "subsession $1 copied to $2" \
+				;
+			;;
+
+		clear )
+			scwrypts -n --name set-context --type zsh --group kubectl -- --subsession $SUBSESSION reset >/dev/null \
+				&& SUCCESS "subsession $SUBSESSION reset to default"
+			;;
+
+		show )
+			_SCWRYPTS_KUBECTL_SETTINGS set context show >/dev/null \
+				&& SUCCESS "now showing full command context"
+			;;
+
+		hide )
+			_SCWRYPTS_KUBECTL_SETTINGS set context hide >/dev/null \
+				&& SUCCESS "now hiding command context"
+			;;
+
+		loose )
+			_SCWRYPTS_KUBECTL_SETTINGS set strict 0 >/dev/null \
+				&& WARNING "now running in 'loose' mode"
+			;;
+
+		strict )
+			_SCWRYPTS_KUBECTL_SETTINGS set strict 1 >/dev/null \
+				&& SUCCESS "now running in 'strict' mode"
+			;;
+	esac
+}
+
+SCWRYPTS_KUBECTL_CUSTOM_COMMAND_DESCRIPTION__meta() {
+	[ $CLI ] || CLI='kubectl'
+	echo "operations for $CLI session variables and other CLI settings"
+}

plugins/kubectl/get-context

@@ -0,0 +1,16 @@
+#!/bin/zsh
+#####################################################################
+DEPENDENCIES+=()
+REQUIRED_ENV+=()
+
+use kubectl --group kubectl
+
+CHECK_ENVIRONMENT
+#####################################################################
+
+MAIN() {
+	KUBECTL__GET_CONTEXT
+}
+
+#####################################################################
+MAIN $@

plugins/kubectl/get-namespace

@@ -0,0 +1,16 @@
+#!/bin/zsh
+#####################################################################
+DEPENDENCIES+=()
+REQUIRED_ENV+=()
+
+use kubectl --group kubectl
+
+CHECK_ENVIRONMENT
+#####################################################################
+
+MAIN() {
+	KUBECTL__GET_NAMESPACE
+}
+
+#####################################################################
+MAIN $@

plugins/kubectl/kubectl.scwrypts.zsh

@@ -0,0 +1,11 @@
+SCWRYPTS_GROUPS+=(kubectl)
+
+export SCWRYPTS_TYPE__kubectl=zsh
+export SCWRYPTS_ROOT__kubectl="$SCWRYPTS_ROOT__scwrypts/plugins/kubectl"
+export SCWRYPTS_COLOR__kubectl='\033[0;31m'
+
+SCWRYPTS_STATIC_CONFIG__kubectl+=(
+	"$SCWRYPTS_ROOT__kubectl/.config/static/redis.zsh"
+)
+
+source "$SCWRYPTS_ROOT__kubectl/driver/kubectl.driver.zsh"

plugins/kubectl/lib/kubectl.module.zsh

@@ -0,0 +1,89 @@
+#####################################################################
+
+DEPENDENCIES+=(
+	kubectl
+)
+
+REQUIRED_ENV+=()
+
+use redis --group kubectl
+
+#####################################################################
+
+KUBECTL() {
+	local NAMESPACE=$(REDIS get --prefix "current:namespace")
+	local CONTEXT=$(KUBECTL__GET_CONTEXT)
+
+	local KUBECTL_ARGS=()
+	[ $NAMESPACE ] && KUBECTL_ARGS+=(--namespace $NAMESPACE)
+	[ $CONTEXT   ] && KUBECTL_ARGS+=(--context $CONTEXT)
+
+	kubectl ${KUBECTL_ARGS[@]} $@
+}
+
+
+#####################################################################
+
+KUBECTL__GET_CONTEXT() { REDIS get --prefix "current:context"; }
+
+KUBECTL__SET_CONTEXT() {
+	local CONTEXT=$1
+	[ ! $CONTEXT ] && return 1
+
+	[[ $CONTEXT =~ reset ]] && {
+		: \
+			&& REDIS del --prefix "current:context" \
+			&& KUBECTL__SET_NAMESPACE reset \
+			;
+		return $?
+	}
+
+	: \
+		&& REDIS set --prefix "current:context" "$CONTEXT" \
+		&& KUBECTL__SET_NAMESPACE reset \
+		;
+}
+
+KUBECTL__SELECT_CONTEXT() {
+	KUBECTL__LIST_CONTEXTS | FZF 'select a context'
+}
+
+KUBECTL__LIST_CONTEXTS() {
+	echo reset
+	local ALL_CONTEXTS=$(KUBECTL config get-contexts -o name | sort)
+
+	echo $ALL_CONTEXTS | grep -v '^arn:aws:eks'
+
+	[[ $AWS_ACCOUNT ]] && {
+		echo $ALL_CONTEXTS | grep "^arn:aws:eks:.*:$AWS_ACCOUNT"
+		true
+	} || {
+		echo $ALL_CONTEXTS | grep '^arn:aws:eks'
+	}
+}
+
+#####################################################################
+
+KUBECTL__GET_NAMESPACE() { REDIS get --prefix "current:namespace"; }
+
+KUBECTL__SET_NAMESPACE() {
+	local NAMESPACE=$1
+	[ ! $NAMESPACE ] && return 1
+
+	[[ $NAMESPACE =~ reset ]] && {
+		REDIS del --prefix "current:namespace"
+		return $?
+	}
+
+	REDIS set --prefix "current:namespace" "$NAMESPACE"
+}
+
+KUBECTL__SELECT_NAMESPACE() {
+	KUBECTL__LIST_NAMESPACES | FZF 'select a namespace'
+}
+
+KUBECTL__LIST_NAMESPACES() {
+	echo reset
+	echo default
+	KUBECTL get namespaces -o name | sed 's/^namespace\///' | sort
+}

plugins/kubectl/lib/redis.module.zsh

@@ -0,0 +1,97 @@
+#####################################################################
+
+DEPENDENCIES+=(
+	redis-cli
+	docker
+)
+
+# TODO; allow custom redis configuration
+export SCWRYPTS_KUBECTL_REDIS=managed
+
+REQUIRED_ENV+=(
+	SCWRYPTS_KUBECTL_REDIS
+)
+
+#####################################################################
+
+REDIS() {
+	[ ! $USAGE ] && local USAGE="
+		usage: [...options...]
+
+		options:
+		  --subsession [0-9]   use a particular subsession
+
+		  -p, --prefix   apply dynamic prefix to the next command line argument
+
+		  --get-prefix              output key prefix for current session+subsession
+		  --get-static-definition   output the static ZSH function definition for REDIS
+
+		  additional arguments and options are passed through to 'redis-cli'
+	"
+
+	local REDIS_ARGS=() USER_ARGS=()
+
+	[ $SUBSESSION ] || local SUBSESSION=0
+
+	local REDIS_PREFIX=$(eval echo '$SCWRYPTS_KUBECTL_REDIS_KEY_PREFIX__'$SCWRYPTS_KUBECTL_REDIS)
+	[ $REDIS_PREFIX ] && REDIS_PREFIX+=':'
+
+	while [[ $# -gt 0 ]]
+	do
+		case $1 in 
+			-p | --prefix ) USER_ARGS+=("${REDIS_PREFIX}${SCWRYPTS_ENV}:${SUBSESSION}:$2"); shift 1 ;;
+
+			--subsession            ) SUBSESSION=$2; shift 1 ;;
+
+			--get-prefix            ) echo $REDIS_PREFIX; return 0 ;;
+			--get-static-definition ) ECHO_STATIC_DEFINITION=1 ;;
+
+			* ) USER_ARGS+=($1) ;;
+		esac
+		shift 1
+	done
+
+	local REDIS_HOST=$(eval echo '$SCWRYPTS_KUBECTL_REDIS_HOST__'$SCWRYPTS_KUBECTL_REDIS)
+	local REDIS_PORT=$(eval echo '$SCWRYPTS_KUBECTL_REDIS_PORT__'$SCWRYPTS_KUBECTL_REDIS)
+	local REDIS_AUTH=$(eval echo '$SCWRYPTS_KUBECTL_REDIS_AUTH__'$SCWRYPTS_KUBECTL_REDIS)
+
+	[ $REDIS_HOST ] && REDIS_ARGS+=(-h $REDIS_HOST)
+	[ $REDIS_PORT ] && REDIS_ARGS+=(-p $REDIS_PORT)
+	[ $REDIS_AUTH ] && REDIS_ARGS+=(-a $REDIS_AUTH)
+
+	REDIS_ARGS+=(--raw)
+
+	[[ $ECHO_STATIC_DEFINITION -eq 1 ]] && {
+		echo "REDIS() {\
+			local USER_ARGS=(); \
+			[ ! \$SUBSESSION ] && local SUBSESSION=0 ;\
+			while [[ \$# -gt 0 ]]; \
+			do \
+				case \$1 in
+				-p | --prefix ) USER_ARGS+=(\"${REDIS_PREFIX}\${SCWRYPTS_ENV}:\${SUBSESSION}:\$2\"); shift 1 ;; \
+				* ) USER_ARGS+=(\$1) ;; \
+				esac; \
+				shift 1; \
+			done; \
+			redis-cli ${REDIS_ARGS[@]} \${USER_ARGS[@]}; \
+		}" | sed 's/\s\+/ /g'
+		return 0
+	}
+
+	redis-cli ${REDIS_ARGS[@]} ${USER_ARGS[@]}
+}
+
+REDIS ping | grep -qi pong || {
+	RPID=$(docker ps -a | grep scwrypts-kubectl-redis | awk '{print $1;}')
+	[ $RPID ] && STATUS 'refreshing redis instance' && docker rm -f $RPID
+	unset RPID
+
+	docker run \
+		--detach \
+		--name scwrypts-kubectl-redis \
+		--publish $SCWRYPTS_KUBECTL_REDIS_PORT__managed:6379 \
+		redis >/dev/null 2>&1
+
+	STATUS 'awaiting redis connection'
+	until REDIS ping 2>/dev/null | grep -qi pong; do sleep 0.5; done
+}

plugins/kubectl/meta/get-static-redis-definition

@@ -0,0 +1,11 @@
+#!/bin/zsh
+#####################################################################
+DEPENDENCIES+=()
+REQUIRED_ENV+=()
+
+use redis --group kubectl
+
+CHECK_ENVIRONMENT
+#####################################################################
+
+echo $(REDIS --get-static-definition)

plugins/kubectl/set-context

@@ -0,0 +1,46 @@
+#!/bin/zsh
+#####################################################################
+DEPENDENCIES+=()
+REQUIRED_ENV+=()
+
+use kubectl --group kubectl
+
+CHECK_ENVIRONMENT
+#####################################################################
+
+MAIN() {
+	local USAGE="
+	usage: [context] [...options...]
+
+	args:
+	  context   (optional) the full name of the kubeconfig context to set
+
+	options:
+	  --subsession   REDIS subsession (default 0)
+	"
+	local CONTEXT
+	local SUBSESSION=0
+
+	while [[ $# -gt 0 ]]
+	do
+		case $1 in
+			--subsession ) SUBSESSION=$2; shift 1 ;;
+
+			* )
+				[ $CONTEXT ] && ERROR "unexpected argument '$2'"
+				CONTEXT=$1
+				;;
+		esac
+		shift 1
+	done
+
+	[ $CONTEXT ] || CONTEXT=$(KUBECTL__SELECT_CONTEXT)
+	[ $CONTEXT ] || ERROR 'must provide or select a valid kube context'
+
+	CHECK_ERRORS
+
+	KUBECTL__SET_CONTEXT $CONTEXT
+}
+
+#####################################################################
+MAIN $@

plugins/kubectl/set-namespace

@@ -0,0 +1,46 @@
+#!/bin/zsh
+#####################################################################
+DEPENDENCIES+=()
+REQUIRED_ENV+=()
+
+use kubectl --group kubectl
+
+CHECK_ENVIRONMENT
+#####################################################################
+
+MAIN() {
+	local USAGE="
+	usage: [namespace] [...options...]
+
+	args:
+	  namespace   (optional) the full name of the namespace context to set
+
+	options:
+	  --subsession   REDIS subsession (default 0)
+	"
+	local NAMESPACE
+	local SUBSESSION=0
+
+	while [[ $# -gt 0 ]]
+	do
+		case $1 in
+			--subsession ) SUBSESSION=$2; shift 1 ;;
+
+			* )
+				[ $NAMESPACE ] && ERROR "unexpected argument '$2'"
+				NAMESPACE=$1
+				;;
+		esac
+		shift 1
+	done
+
+	[ $NAMESPACE ] || NAMESPACE=$(KUBECTL__SELECT_NAMESPACE)
+	[ $NAMESPACE ] || ERROR 'must provide or select a valid namespace'
+
+	CHECK_ERRORS
+
+	KUBECTL__SET_NAMESPACE $NAMESPACE
+}
+
+#####################################################################
+MAIN $@

zsh/lib/cloud/aws/ecr.module.zsh

@@ -4,16 +4,15 @@ DEPENDENCIES+=(
 	docker
 )
 
-REQUIRED_ENV+=(
+REQUIRED_ENV+=()
-	AWS_ACCOUNT
-	AWS_REGION
-)
 
 use cloud/aws/cli
 
 #####################################################################
 
 ECR_LOGIN() {
+	REQUIRED_ENV=(AWS_REGION AWS_ACCOUNT) CHECK_ENVIRONMENT || return 1
+
 	STATUS "performing AWS ECR docker login"
 	AWS ecr get-login-password \
 		| docker login \

zsh/lib/config.zsh

@@ -39,4 +39,11 @@ source "$SCWRYPTS_ROOT/zsh/lib/config.group.zsh" \
 	|| FAIL 69 'failed to set up scwrypts group; aborting'
 
 #####################################################################
-__SCWRYPT=1 # arbitrary; indicates currently inside a scwrypt
+
+[[ $SCWRYPTS_PLUGIN_ENABLED__kubectl -eq 1 ]] && {
+	source "$SCWRYPTS_ROOT/plugins/kubectl/kubectl.scwrypts.zsh"
+}
+
+#####################################################################
+[ $NO_EXPORT_CONFIG ] || __SCWRYPT=1 # arbitrary; indicates currently inside a scwrypt
+true

zsh/lib/scwrypts/run.module.zsh

@@ -54,6 +54,7 @@ SCWRYPTS__LIST_AVAILABLE_SCWRYPTS__scwrypts() {
 		| grep -v '\.git' \
 		| grep -v 'node_modules' \
 		| sed "s/^\\.\\///; s/\\.[^.]*$//; s/^/$GROUP_TYPE/" \
+		| grep -v '^plugins/' \
 		;
 }
 

zsh/lib/utils/io.zsh

@@ -55,37 +55,81 @@ ABORT() { FAIL 69 'user abort'; }
 
 CHECK_ERRORS() {
 	local FAIL_OUT=1
+	local DISPLAY_USAGE=1
 
 	while [[ $# -gt 0 ]]
 	do
 		case $1 in
-			-n | --no-fail ) FAIL_OUT=0 ;;
+			--no-fail  ) FAIL_OUT=0 ;;
+			--no-usage ) DISPLAY_USAGE=0 ;;
 		esac
 		shift 1
 	done
 
 	[ ! $ERRORS ] && ERRORS=0
-	[[ $ERRORS -ne 0 ]] && USAGE
+	[[ $ERRORS -eq 0 ]] && return 0
-	[[ $ERRORS -eq 0 ]] || {
+
-		[[ $FAIL_OUT -eq 1 ]] \
+	[[ $DISPLAY_USAGE -eq 1 ]] && USAGE
-			&& exit $ERRORS \
+
-			|| return $ERRORS
+	[[ $FAIL_OUT -eq 1 ]] && exit $ERRORS
-	}
+
+	return $ERRORS
 }
 
-USAGE() {
+USAGE() { # formatter for USAGE variable
 	[ ! $USAGE ] && return 0
-	USAGE=$(echo $USAGE | sed "s/^\t\+//; s/\s\+$//")
+	local USAGE_LINE=$(echo $USAGE | grep -i '^[	]*usage *:' | sed 's/^[		]*//')
 
-	local USAGE_LINE=$(\
+	[ $USAGE__usage ] && echo $USAGE_LINE | grep -q 'usage: -' \
-		echo $USAGE \
+		&& USAGE_LINE=$(echo $USAGE_LINE | sed "s/usage: -/usage: $USAGE__usage/")
-			| grep -i '^ *usage *:' \
-			| sed "s;^[^:]*:;& scwrypts $SCWRYPT_NAME --;" \
-			| sed 's/ \{2,\}/ /g; s/scwrypts -- scwrypts/scwrypts/' \
-		)
-	local THE_REST=$(echo $USAGE | grep -vi '^ *usage *:' | sed 'N;/^\n$/D;P;D;')
 
-	{ echo; printf "$__DARK_BLUE $USAGE_LINE$__COLOR_RESET\n"; echo $THE_REST; echo } >&2
+	[ $__SCWRYPT ] \
+		&& USAGE_LINE=$(
+			echo $USAGE_LINE \
+				| sed "s;^[^:]*:;& scwrypts $SCWRYPT_NAME --;" \
+				| sed 's/ \{2,\}/ /g; s/scwrypts -- scwrypts/scwrypts/' \
+			)
+
+	local THE_REST=$(echo $USAGE | grep -vi '^[		]*usage *:' )
+
+	local DYNAMIC_USAGE_ELEMENT
+	#
+	# create dynamic usage elements (like 'args') by defining USAGE__<element>
+	# then using the syntax "<element>: -" in your USAGE variable
+	#
+	# e.g.
+	#
+	# USAGE__args="
+	#	subcommand arg 1   arg 1 description
+	#   subcommand arg 2   some other description
+	# "
+	#
+	# USAGE="
+	# usage: some-command [...args...]
+	#
+	# args: -
+	#   -h, --help   some arguments are applicable everywhere
+	# "
+	#
+	for DYNAMIC_USAGE_ELEMENT in $(echo $THE_REST | sed -n 's/^\([^:]*\): -$/\1/p')
+	do
+		DYNAMIC_USAGE_ELEMENT_TEXT=$(eval echo '$USAGE__'$DYNAMIC_USAGE_ELEMENT)
+
+		[[ ! $DYNAMIC_USAGE_ELEMENT =~ ^description$ ]] \
+			&& DYNAMIC_USAGE_ELEMENT_TEXT=$(echo $DYNAMIC_USAGE_ELEMENT_TEXT | sed 's/[^	]/  &/')
+
+		THE_REST=$(echo $THE_REST | perl -pe "s/$DYNAMIC_USAGE_ELEMENT: -/$DYNAMIC_USAGE_ELEMENT:\n$DYNAMIC_USAGE_ELEMENT_TEXT\n\n/")
+	done
+
+	# allow for dynamic 'description: -' but delete the 'description:' header line
+	THE_REST=$(echo $THE_REST | sed '/^[		]*description:$/d')
+
+	echo "$__DARK_BLUE$USAGE_LINE$__COLOR_RESET\n\n$THE_REST" \
+		| sed "s/^\t\+//; s/\s\+$//; s/^\\s*$//;" \
+		| sed '/./,$!d; :a; /^\n*$/{$d;N;ba;};' \
+		| perl -p0e 's/\n{2,}/\n\n/g' \
+		| perl -p0e 's/:\n{2,}/:\n/g' \
+		>&2
 }
 
 INPUT() {